'元HTMLファイルから、インデックス付きのHTMLファイルを作る
INDEX=『』
「tmp-*.htm」の、ファイル列挙。'テンプレート用のhtmlファイルを読む。
それを、ソート。
それを、言う。
それを、反復(
	HTMLファイル名は、それ。
	それを、開く。
	HTMLは、それ。
	HTMLから、"TITLE"の、タグ切り出し。
	それから、タグ削除。
	タイトル=それ。
	HTMLファイル名を、「.htm」に、拡張子変更。
	4文字、左端削除。
	新ファイル名は、それ。
	インデックス作成を、呼ぶ。
	それは、HTML
	INDEX=INDEX&「<A href=\"{新ファイル名}\">■{タイトル}</A>\n」&
		「<BLOCKQUOTE>{INDEX目次}</BLOCKQUOTE>」
	新ファイル名へ、保存。
)。
『index.tmp』を、開く。
「@@LINK@@」を、INDEXに、置換。
「@@TODAY@@」を、今日に、置換。
『index.htm』へ、保存。
『index.htm』を、起動。
おわり。

＊インデックス作成
完成文=『』
目次は、「」
INDEX目次=""
HTMLの、『<HR>』までを、切り取る。
ヘッダは、それ。
CNT=1
＊繰り返しラベル
HTMLの、『<HR>』までを、切り取る。
もし、HTMLが、「」でなければ(
Q=それ
Qから、「H2」の、タグ切り出し。
それから、タグ削除。
質問名は、それ。
もし、質問名が、『』ならば(
	完成文=完成文&Q
)違えば(
	完成文=完成文&「<A name=\"{CNT}\">No.{CNT}</A>」&Q&『<HR>』
	目次は、目次&「<A href=\"#{CNT}\">({CNT}) {質問名}</A><BR>\n」
	INDEX目次=INDEX目次&「<A href=\"{新ファイル名}#{CNT}\">({CNT}) {質問名}</A><BR>\n」
)。
白色で、画面クリア。
Qを、表示。
CNT=CNT+1
繰り返しラベルへ、飛ぶ。
)

＊繰り返しラベル終わり
HTML=ヘッダ&目次&"<HR>"&完成文＆"</BODY></HTML>"。
戻る。
